热门 函数365之SUMIF函数:我是来求和的,你有什么条件?

时间:2017-2-28   作者:一村之长   分类: Excel函数   热度:1307°    
时间:2017-2-28   分类: Excel函数    热度:1307  
函数名称:SUMIF

函数作用:使用SUMIF函数可以对区域中符合指定条件的值求和。

函数语法:SUMIF(条件区域,指定条件,求和区域)

注意事项:
1、第1参数为用于条件计算的单元格区域。每个区域中的单元格都必须是数字或名称、数组或包含数字的引用。空值和文本值将被忽略。

2、第2参数为用于确定对哪些单元格求和的条件,其形式可以为数字、表达式、单元格引用、文本或函数。

3、第3参数为要求和的实际单元格(如果要对未在 range 参数中指定的单元格求和)。如果第3参数被省略,Excel 会对在第1参数中指定的单元格(即应用条件的单元格)求和。

4、第1和第2参数为必选参数,第三参数为可选参数。

函数应用:
实例1、根据下表按要求分别计算。
1、计算销量大于200的销量总和;
2、计算姓“陈”的业务员的销量总和;
1.png

函数公式1:=SUMIF(C2:C14,">200",C2:C14),结果为4680。
解释说明:本题用SUMIF函数根据销量条件进行求和,所以C列既是条件区域,也是求和区域,公式也可以写成=SUMIF(C2:C14,">200"),直接省略第3参数。

函数公式2:=SUMIF(B2:B14,"陈*",C2:C14),结果为1507
解释说明:本题主要考的是SUMIF函数的条件支持通配符“*”和“?”,所以这里用“陈*”表示姓陈的人员。

实例2、根据下面表格计算张三的销量总和。
2.png

函数公式1:=SUMIF(A2:F11,"张三",B2),结果为556

解释说明:本题主要考的是SUMIF的第3参数,SUMIF的第3参数范围取决于第1参数的区域范围,条件区域的每一个单元格分别对应求和区域的每一个单元格,所以当A2对应B2,其它的A3对应B3…C4对应D4…等等依次类推


2.png

热门 函数365之WEEKDAY函数:今天星期几我来告诉你

时间:2017-2-27   作者:一村之长   分类:   热度:2638°    
时间:2017-2-27   分类:    热度:2638  
函数名称:WEEKDAY

函数作用:返回某日期为星期几。默认情况下,其值为 1(星期天)到 7(星期六)之间的整数。

函数语法:WEEKDAY(日期值,返回值类型)

返回值类型:
1、返回值类型为1或省略时,WEEKDAY结果为数字 1(星期日)到数字 7(星期六)。
2、返回值类型为2时,WEEKDAY结果为数字 1(星期一)到数字 7(星期日)。
3、返回值类型为3时,WEEKDAY结果为数字 0(星期一)到数字 6(星期日)。
4、返回值类型为11时,WEEKDAY结果为数字 1(星期一)到数字 7(星期日)。
5、返回值类型为12时,WEEKDAY结果为数字 1(星期二)到数字 7(星期一)。
6、返回值类型为13时,WEEKDAY结果为数字 1(星期三)到数字 7(星期二)。
7、返回值类型为14时,WEEKDAY结果为数字 1(星期四)到数字 7(星期三)。
8、返回值类型为15时,WEEKDAY结果为数字 1(星期五)到数字 7(星期四)。
9、返回值类型为16时,WEEKDAY结果为数字 1(星期六)到数字 7(星期五)。
10、返回值类型为17时,WEEKDAY结果为数字 1(星期日)到 7(星期六)。

注:一般工作中比较常用的类型是1或者2.

函数应用:
实例1、请计算2017年2月份周六周日合计有多少天。

函数公式1:=SUMPRODUCT(N(WEEKDAY("2017-2-"&ROW(1:28),2)>5)),结果为8
解释说明:
1、本题用"2017-2-"&ROW(1:28)表示2017年2月的每一天的日期;

2、然后再用WEEKDAY函数判断每一个日期返回的值,返回值的类型为2,表示当WEEKDAY函数的结果为1-7的时候,分别对应星期一到星期日;

3、所以WEEKDAY("2017-2-"&ROW(1:28),2)>5表示判断该返回值是否大于5,如果是则表示是周末(结果为TRUE),否则则不是(结果为FALSE);

4、然后再用N函数将TRUE转化为1,将FALSE转化为0,最后再用SUMPRODUCE函数将结果全部相加,结果就是全部星期六和星期日的天数之和。

思维拓展:假定要求计算的年份和月份是动态变化的,也就是说根据当前的时间变化而变化,时间有可能是2月,也有可能是3月,甚至可能是2018年2月,那么又该如何写函数计算呢?欲知后事如何请看以后分析!

实例2、下表是一个日历表格,年份和月份是动态变化的,要求根据下面表格写入函数公式,使得年份或月份动态变化时日期值随之变化。
1.png


函数公式1:=TEXT(TEXT(7*ROW(A1)+COLUMN(A1)-WEEKDAY($A$2&"-"&$B$2&"-1",1)-6,"[>0]0;"),"[<="&DAY(EOMONTH($A$2&"-"&$B$2&"-1",0))&"]0;"),公式写在A4单元格,右拉下拉即可。

解释说明:
1、本题最关键的是要推导出当月1日在表中的哪个位置,所以这里用的是WEEKDAY函数,$A$2&"-"&$B$2&"-1"表示指定月份的1日,返回值类型为1;

2、因为返回值类型为1的WEEKDAY结果1-7分别表示星期日到星期六,与上表相符,所以WEEKDAY的结果就是指定月份的1日的位置;

3、因为是日历,所以从左到右的数字应该是公差为1的等差数列,所以用1-WEEKDAY($A$2&"-"&$B$2&"-1",1)+1就可以倒推出左边第一个单元格(A4)的值是多少;

4、因为是日历,所以从上到下的数字应该是公差为7的等差数列,根据A4单元格的值(左右等差数列、上下等差数列的首项)可以得到公式7*ROW(A1)+COLUMN(A1)-WEEKDAY($A$2&"-"&$B$2&"-1",1)-6;

5、由于上面的公式可能会出现负值或者大于本月最大天数的日期,所以需要判断出这些日期然后避免出现这些情况,这里为了省字符就不用IF做判断,而是用TEXT函数。

热门 函数365之HYPERLINK函数:打开传送之门

时间:2017-2-26   作者:一村之长   分类: Excel函数   热度:1284°    
时间:2017-2-26   分类: Excel函数    热度:1284  
1
函数名称

HYPERLINK

2
函数作用

HYPERLINK函数用于创建快捷方式或跳转,用以打开存储在网络服务器、Intranet 或 Internet 中的文档。

3
函数语法

HYPERLINK(要打开的文档的路径和文件名, 显示的链接名称)

注意事项

1、第1参数可以是括在引号中的文本字符串,也可以是对包含文本字符串链接的单元格的引用。

2、第2参数可以为数值、文本字符串、名称或包含跳转文本或数值的单元格。

3、如果第2参数返回错误值(例如,#VALUE!),单元格将显示错误值以替代跳转文本。

函数应用

实例一

某网站地址www.1excel.net,现在要求在单元格中做一个超链接,点击链接可以打开该网站地址,链接名称显示“我的Excel”。函数公式

=HYPERLINK("http://www.1excel.net","我的Excel")


解释说明
▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼

HYPERLINK函数在做网站超链接的时候网址需要以“http://”开头,否则链接地址会无法打开。

▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼



实例二

有一个工作簿,工作簿里面有N个工作表,工作表会动态增加,要求建立一个以每个工作表名称命名的超链接,如下图:


1.png
















操作步骤

1、查看工作簿是不是xls格式,如果不是另存为xls格式;

2、打开公式选项卡,然后打开名称管理器,新建名称“sheets”,引用位置处输入公式=GET.WORKBOOK(1)&T(NOW()),如下图2.png

3、在A2单元格输入公式=IFERROR(HYPERLINK(INDEX(sheets,ROW(A1))&"!A1",REPLACE(INDEX(sheets,ROW(A1)),1,FIND("]",INDEX(sheets,ROW(A1))),"")),""),公式下拉即可得到我们要的效果,如题目图所示。

解释说明
▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼

1、公式=GET.WORKBOOK(1)是宏表函数可以获取工作表名称,至于为什么要用&连接T(NOW())是因为该宏表函数获取的信息不会实时更新,而NOW是时间函数可以实时更新计算;

2、INDEX(sheets,ROW(A1))下拉后可以获得所有工作表名称,将名称用&连接A1表示引用每个工作表的A1单元格;

3、INDEX(sheets,ROW(A1))下拉后可以获得所有工作表名称,但是工作表名称显示的格式是“[工作簿名称]工作表名称”,所以要用REPLACE函数将“[工作簿名称]”这一部分去除掉,所以这里用了FIND函数查询“]”符号在名称中的位置,该位置数值就是REPLACE函数要清除的字符总数。

4、公式用了IFERROR函数是为了保证下拉的时候不会出现错误值,当出现错误值,单元格为空。


▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼


结束语

截止今天,公众号关注粉丝211人,人数虽少,但是星星之火可以燎原,坚定本心,矢志不渝,终能乘风破浪!

2.png


热门 函数365之MAX/MIN函数:最大最小最奇妙

时间:2017-2-25   作者:一村之长   分类: Excel函数   热度:2716°    
时间:2017-2-25   分类: Excel函数    热度:2716  
函数名称:MAX与MIN

函数作用:MAX函数用于返回一组值中的最大值,MIN函数用于返回一组值中的最小值,刚好相反。

函数语法:
MAX(参数1, 参数2, 参数3, ..., 参数255)
MIN(参数1, 参数2, 参数3, ..., 参数255)

注意事项:
1、函数共有255个参数,其中第1参数为必选参数,其余为可选参数。
2、参数可以是数字或者是包含数字的名称、数组或引用。
3、逻辑值和直接键入到参数列表中代表数字的文本被计算在内。
4、如果参数为数组或引用,则只使用该数组或引用中的数字。数组或引用中的空白单元格、逻辑值或文本将被忽略。
5、如果参数不包含数字,函数 MAX/MIN 返回 0(零)。
6、如果参数为错误值或为不能转换为数字的文本,将会导致错误。
7、如果要使计算包括引用中的逻辑值和代表数字的文本,请使用 MAXA/MINA 函数。

函数应用:
实例1、某公司规定,凡员工绩效分数小于60分的,每少1分扣10元,最多扣150元,大于等于60分不奖不罚,根据下表计算每个员工的扣款情况。
1.png
函数公式:=MIN(MAX((60-B2)*10,0),150),公式下拉即可
解释说明:本题用60-B2计算出该员工绩效分数比60分少多少,(60-B2)*10则可以计算出扣款金额,用MAX函数将(60-B2)*10与0做比较取最大值,是为了防止扣款金额出现负数的情况,因为0比负数大,然后用MIN函数将MAX((60-B2)*10,0)的结果与150做比较取最小值,可以防止扣款超过150元。

实例2、根据下面个税表格计算个人所得税。
2.png
函数公式:=MAX((B2-C2-3500)*{0.03,0.1,0.2,0.25,0.3,0.35,0.45}-{0,105,555,1005,2775,5505,13505},0)
解释说明:
1、B2-C2-3500可以计算出应纳税所得额
2、将应纳税所得额依次乘以每一个税率然后分别减去对应的速算扣除数,然后用MAX取最大值即为个人所得税;
3、MAX多加了一个参数0,表示将计算的个人所得税与0做比较取最大值,防止个人所得税出现负数的情况。


2.png

热门 函数365之MATCH函数:查找你在我心里位置

时间:2017-2-24   作者:一村之长   分类: Excel函数   热度:1148°    
时间:2017-2-24   分类: Excel函数    热度:1148  
1
函数名称

MATCH

2
函数作用

MATCH函数可在单元格区域中搜索指定项,然后返回该项在单元格区域中的相对位置。

3
函数语法

MATCH(查找条件,查找区域,查找方式)

查找方式

1、当第3参数为1或省略时,函数会查找小于或等于查找条件的最大值,查找区域的值必须按升序排列

2、当第3参数为-1时,函数会查找大于或等于查找条件的最小值,查找区域的值必须按降序排列;

3、当第3参数为0时,函数会查找等于查找条件的值,查找区域的值不受限制。

注意事项

1、在MATCH函数中,查找条件不区分字母大小;

2、当MATCH函数查找不到匹配的结果的时候,结果会返回#N/A错误值;

3、MATCH函数支持“*”和“?”通配符。

函数应用

实例一

根据条件查找销量(条件姓名和月份会随机改变)

1.png














函数公式

=VLOOKUP(A11,A1:F8,MATCH(B11,A1:F1,0),0),结果为951,如图所示。

▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼

本题用VLOOKUP函数根据姓名在A1:F8区域中进行查找,因为月份是随机变化的,所以VLOOKUP返回的列数也会随机变化,这个时候用MATCH函数可以查找到月份在A1:F1的具体位置,也就是我们VLOOKUP函数要返回的列数。

▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼



实例二

根据下面表格提取不重复姓名。

2.png

函数公式

=IFERROR(INDEX($A$2:$A$15,SMALL(IF(MATCH($A$2:$A$15,$A$2:$A$15,0)=ROW($1:$14),ROW($1:$14),9^9),ROW(A1))),""),数组公式,需CTRL+SHIFT+回车键三键结束,公式下拉即可

▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼

1、本题用MATCH函数将A2:A15单元格区域的每一个单元格依次在A2:A15单元格区域查找一次位置,当查找的结果等于当前排列的位置时,该姓名为第一次出现,否则则为重复。

2、IF函数判断姓名不重复时返回1:14的位置,如果重复返回9^9(代表一个极大的数,超过表格最大引用行数)。

3、SMALL函数将所有数值从小到大依次排列,然后用INDEX函数根据位置引用单元格内容,超出引用行数的返回错误值,所以需要IFERROR函数对INDEX函数的结果进行纠错。

▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼


结束语

时间的步伐有三种:未来姗姗来迟,现在像箭一样飞逝,过往永远静立不动。

                                                                            — —席勒

2.png



热门 函数365之AND/OR函数:并且与或者的逻辑判断

时间:2017-2-23   作者:一村之长   分类: Excel函数   热度:1402°    
时间:2017-2-23   分类: Excel函数    热度:1402  
1
函数名称

AND函数、OR函数

2
函数作用

AND函数与OR函数都可以对多个不同的逻辑条件进行判断,不同的是AND函数所有条件为 TRUE 时结果返回 TRUE,只要有一个条件为 FALSE即返回 FALSE;而OR函数只要有一个或一个以上条件为TRUE时即返回TRUE,所有条件为FALSE时结果才为FALSE。

3
函数语法

AND(逻辑判断1, 逻辑判断2, 逻辑判断3, ..., 逻辑判断255)

OR(逻辑判断1, 逻辑判断2, 逻辑判断3, ..., 逻辑判断255)

注意事项

1、参数的计算结果必须是逻辑值(如 TRUE 或 FALSE),或者参数必须是包含逻辑值的数组或引用。2、如果数组或引用参数中包含文本或空白单元格,则这些值将被忽略。

3、如果指定的单元格区域未包含逻辑值,则 AND 函数将返回错误值 #VALUE!。

4、第1个参数为必选参数,后面254个参数为可选参数。


函数应用

实例一

根据下表数据和问题做出判断。

问题1:假设每个人5个科目全部大于等于60分则为“优秀”,判断每个人的成绩是否为优秀;

问题2:假设每个人只要有一个或一个以上科目等于100分并且全部科目大于50分则为“优秀”,判断每个人的成绩是否为优秀。

2.png













问题1公式

=IF(AND(B2:F2>=60),"优秀",""),数组公式,需CTRL+SHIFT+回车键三键结束,公式下拉即可

解释说明
▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼

用AND函数判断是否B2:F2所有单元格都大于等于60分,如果是则返回TRUE,只要有一个小于60分则返回FALSE,再嵌套IF函数即可判断是否为“优秀”

▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼

问题2公式

=IF(AND(OR(B2:F2=100),AND(B2:F2>50)),"优秀",""),数组公式,需CTRL+SHIFT+回车键三键结束,公式下拉即可


解释说明
▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼

用OR函数判断B2:F2里面是否存在等于100的数,然后用AND函数判断B2:F2是否都大于50,最后再用个AND函数嵌套前面的OR函数和AND函数的结果,判断出来的就是我们要的结果,然后嵌套IF函数

▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼▼


实例二

根据下面要求在表格区域A2:A100设置数据有效性,写出操作步骤。

要求:

1、A列为销售单号字段,单号格式为YYYYMM+四位流水号,YYYYMM表示制单当月的日期;

2、要求A2单元格只能输入当月的第1号单据,例如2月份则A2单元格只能输入2017020001,禁止跳号,例如A2单元格输入2017020001,A3单元格只能输入2017020002,输入其他会弹出禁止信息。

操作步骤

⊙选中单元格区域A2:A100;

⊙选择“数据”选项卡,然后选择“数据有效性—设置—(允许)自定义”;

⊙输入公式=AND(LEFT(A2,6)=TEXT(NOW(),"YYYYMM"),LEN(A2)=10,A2=IFERROR(--A1,--TEXT(NOW(),"YYYYMM")&"0000")+1),然后点击保存;

⊙操作如下图:

1.png

结束语

今天是第3天连续更新公众号,离小目标365天还有很长很长的路要走,我对我自己很有信心,每一天的文章分享都是我对自己学过的知识的总结,可以让我对学过的知识有一个更深刻的认知和了解,每一天的文章分享都是我想要告诉大家我对于Excel函数的理解,希望能对大家学习函数有所帮助,当我坚持完成365天的函数分享的时候,我希望能有人坚持365天关注我的公众号,我会尽我最大的努力给大家最好的分享。


《一村之长写于2017年2月22日23:54:17》

1.png


热门 函数365之ADDRESS函数:单元格引用与多表动态引用

时间:2017-2-22   作者:一村之长   分类: Excel函数   热度:4102°    
时间:2017-2-22   分类: Excel函数    热度:4102  
函数名称: ADDRESS

函数作用: 在给出指定行数和列数的情况下,可以使用 ADDRESS 函数获取工作表单元格的地址。

函数语法: ADDRESS(行号, 列号, 引用类型, 引用样式, 引用的工作表名称)

注意事项:
引用类型主要有四类:
1或省略表示绝对单元格引用
2表示绝对行号,相对列标 
3表示相对行号,绝对列标 
4表示相对单元格引用
引用样式主要有两种:
A1引用样式中,表示的是列和行将分别按字母和数字顺序添加标签,参数可用“1”表示
R1C1引用样式中,列和行均按数字顺序添加标签,参数可用“0”表示
注:第1、第2参数为必选参数,其中第3、第4、第5参数均为可选参数。

函数应用:
实例1、请用函数生成A-AZ的序列
函数公式: =SUBSTITUTE(ADDRESS(1,ROW(A1),4),1,""),公式下拉即可
解释说明: ADDRESS第1参数用1表示取单元格第1行,第2参数用ROW(A1),公式下拉的时候会依次取得1,2,3,4…的序列,分别表示第1,2,3,4…列,所以整个公式可以取得A1-AZ1单元格,再用替换函数SUBSTITUTE将单元格A1-AZ1的行号“1”替换为空,即可得到答案。

实例2、下表中有多个工作表,每个工作表格式相同A/B两列为表格内容,A列姓名,B列销量,每个部门人员不超过100个,要求写一个公式,可以根据部门汇总不同部门的销量总和。
1.png3.png

函数公式: =SUMPRODUCT(N(INDIRECT(ADDRESS(ROW(2:101),2,4,1,A2))))
解释说明: 1、ADDRESS函数第1参数为ROW(2:101)表示取表格中的第2行至第101行,共100个单元格(因为题目说人员不超过100人);
2、ADDRESS函数第2参数为2表示固定取表格中的第2列(因为题目说表格B列为销量);
3、ADDRESS函数第3参数为4表示单元格引用为相对引用(本题这里选1-4任何一个数字都可以);
4、ADDRESS函数第4参数为1表示单元格引用样式为A1样式;
5、ADDRESS函数第5参数为A2表示引用A2单元格所在的部门为名称的工作表;
6、ADDRESS函数外面嵌套INDIRECT函数表示引用ADDRESS函数所表示的单元格的内容,因为涉及多个单元格,所以需要用INDIRECT函数外面需要嵌套N函数将多维引用将维处理;
7、最后用SUMPRODUCT函数将所有单元格的值相加。
1.png

热门 函数365之ABS函数:计算绝对值

时间:2017-2-21   作者:一村之长   分类: Excel函数   热度:1406°    
时间:2017-2-21   分类: Excel函数    热度:1406  
01

函数名称

ABS

02

函数作用

可用于返回数字的绝对值。

03

函数语法

ABS(number)

04

注意事项

Number  必需。需要计算其绝对值的实数。

05

函数应用


1
1.png

01


司机小李某天下午的营运全是在南北走向的鼓楼大街进行的.假定向南为正,向北为负,他这天下午行车里程如上图(单位:千米),若汽车耗油量为0.1 L/km,这天下午汽车共耗油多少升?


函数公式

=SUMPRODUCT(ABS(A2:A8))*0.1,结果等于8.3L

解释说明

将A2:A8每一个单元格的数值用ABS分别绝对值后再相加,等同于=(ABS(A2)+ABS(A3)+ABS(A4)+ABS(A5)+ABS(A6)+ABS(A7)+ABS(A8))*0.1

2
2.png

02


某工厂生产一批零件,根据零件质量要求:零件的长度可以有0.2㎝的误差,现抽查5个零件,检查数据记录如上表(超过规定长度的厘米数记为正数,不足规定长度的厘米数记为负数),请指出上面表中有多少个零件符合质量要求。



函数公式

=SUMPRODUCT(N(ABS(B2:G2)<0.2)),结果等于4

解释说明

用ABS函数分别将B2:G2单元格的每一个值绝对值,然后与0.2比较,得到TRUE或FALSE的结果,然后用N函数将TRUE转化为1,将FALSE转化为0,最后相加。

3
3.png

03


某钢铁厂承担了为奥运会鸟巢生产某种钢材零件的任务.其中一个车间生产一批圆形机器零件,从中抽取6件进行验证,比规定直径长的毫米数记作正数,比规定直径短的毫米数记作负数,检查记录如上表,请指出上面第几次抽查的零件好一些。



函数公式

=MATCH(MIN(ABS(B2:G2)),ABS(B2:G2),0),公式为数组公式,需CTRL+SHIFT+回车键三键结束,结果等于6,因为第6次的误差最小

解释说明

MIN(ABS(B2:G2))的意思是将B2:G2的每一个单元格绝对值后再取最小值,然后用MATCH判断该最小值在B2:G2的位置。

结束语

大家好,我是一村之长。公众号停发了三个多月了,突然觉得自己好颓废,这几天想了很多,终于下定决心给自己定了一个小目标,我要坚持365天公众号文章的不断更,坚持每天分享至少一个函数,论坛(www.1cunzhang.com)与博客(www.1excel.net)同步更新。内容主要有我们常见并常用的IF函数、SUMIF函数、VLOOKUP函数等,也有我们不常见的DB函数、FV函数、PV函数等我们不常用的财务函数,如果你想学习函数,如果你想知道函数能帮我们做些什么,那么你还在等什么呢?赶紧扫描二维码关注我的公众号,我坚持365天的分享,你坚持365天的阅读,我们都有满满的收获。

点击查看原图
返回顶部    首页    手机版本    后花园   会员注册   
版权所有:我的Excel    站长: 一村之长    主题寒光唯美式V2.4.1  程序:emlog   桂ICP备16002437号-2  我是村长,欢迎光临我的Excel